home *** CD-ROM | disk | FTP | other *** search
/ Openstep 4.2 (Developer) / Openstep Developer 4.2.iso / NextDeveloper / Source / GNU / make / make-3.74 / configure.in < prev    next >
Encoding:
Text File  |  1995-08-01  |  4.0 KB  |  132 lines
  1. dnl Process this file with autoconf to produce a configure script.
  2. AC_REVISION([$Id: configure.in,v 1.48 1995/03/21 21:23:26 roland Exp $])
  3. AC_PREREQ(2.1)dnl        dnl Minimum Autoconf version required.
  4. AC_INIT(vpath.c)dnl        dnl A distinctive file to look for in srcdir.
  5. AC_CONFIG_HEADER(config.h)
  6. AC_CONFIG_SUBDIRS(glob)        dnl Run configure in glob subdirectory.
  7.  
  8. AC_PROG_MAKE_SET
  9. AC_PROG_CC
  10. AC_PROG_INSTALL
  11. AC_PROG_CPP            dnl Later checks need this.
  12. AC_AIX
  13. AC_ISC_POSIX
  14. AC_MINIX
  15. AC_HEADER_STDC
  16. AC_HEADER_DIRENT
  17. AC_TYPE_UID_T            dnl Also does gid_t.
  18. AC_TYPE_PID_T
  19. AC_TYPE_SIGNAL
  20. AC_CHECK_HEADERS(unistd.h limits.h sys/param.h fcntl.h string.h memory.h \
  21.              sys/timeb.h)
  22. AC_PROG_CC_C_O
  23. AC_C_CONST            dnl getopt needs this.
  24. AC_HEADER_STAT
  25.  
  26. AC_SUBST(LIBOBJS)
  27.  
  28. AC_DEFUN(AC_CHECK_SYMBOL, [dnl
  29. AC_MSG_CHECKING(for $1)
  30. AC_CACHE_VAL(ac_cv_check_symbol_$1, [dnl
  31. AC_TRY_LINK(, [extern char *sys_siglist[]; puts(*sys_siglist);],
  32.         ac_cv_check_symbol_$1=yes, ac_cv_check_symbol_$1=no)])
  33. if test "$ac_cv_check_symbol_$1" = yes; then
  34. changequote(,)dnl
  35.   ac_tr_symbol=`echo $1 | tr '[a-z]' '[A-Z]'`
  36. changequote([,])dnl
  37.   AC_DEFINE_UNQUOTED(HAVE_${ac_tr_symbol})
  38. fi
  39. AC_MSG_RESULT($ac_cv_check_symbol_$1)])dnl
  40.  
  41. AC_CHECK_FUNCS(getdtablesize psignal mktemp \
  42.            dup2 getcwd sigsetmask getgroups setlinebuf \
  43.            seteuid setegid setreuid setregid strerror strsignal)
  44. AC_CHECK_SYMBOL(sys_siglist)
  45. AC_CHECK_SYMBOL(_sys_siglist)
  46. AC_FUNC_ALLOCA
  47. AC_FUNC_VFORK
  48. AC_FUNC_SETVBUF_REVERSED
  49. AC_FUNC_GETLOADAVG
  50. AC_FUNC_STRCOLL
  51.  
  52. if test $ac_cv_func_getdtablesize = no; then
  53.   AC_MSG_CHECKING(for sysconf (_SC_OPEN_MAX))
  54.   AC_CACHE_VAL(make_cv_sysconf_open_max, [dnl
  55.   AC_TRY_LINK([#include <unistd.h>], [int max = sysconf (_SC_OPEN_MAX);],
  56.           [make_cv_sysconf_open_max=yes], [make_cv_sysconf_open_max=no])])
  57.   if test $make_cv_sysconf_open_max = yes; then
  58.     AC_DEFINE(HAVE_SYSCONF_OPEN_MAX)
  59.   fi
  60.   AC_MSG_RESULT($make_cv_sysconf_open_max)
  61. fi
  62.  
  63. # Check out the wait reality.
  64. AC_CHECK_HEADERS(sys/wait.h) AC_CHECK_FUNCS(waitpid wait3)
  65. AC_MSG_CHECKING(for union wait)
  66. AC_CACHE_VAL(make_cv_union_wait, [dnl
  67. AC_TRY_LINK([#include <sys/types.h>
  68. #include <sys/wait.h>],
  69.         [union wait status; int pid; pid = wait (&status);
  70. #ifdef WEXITSTATUS
  71. /* Some POSIXoid systems have both the new-style macros and the old
  72.    union wait type, and they do not work together.  If union wait
  73.    conflicts with WEXITSTATUS et al, we don't want to use it at all.  */
  74. if (WEXITSTATUS (status) != 0) pid = -1;
  75. #ifdef WTERMSIG
  76. /* If we have WEXITSTATUS and WTERMSIG, just use them on ints.  */
  77. -- blow chunks here --
  78. #endif
  79. #endif
  80. #ifdef HAVE_WAITPID
  81. /* Make sure union wait works with waitpid.  */
  82. pid = waitpid (-1, &status, 0);
  83. #endif
  84. ],
  85.         [make_cv_union_wait=yes], [make_cv_union_wait=no])])
  86. if test "$make_cv_union_wait" = yes; then
  87.   AC_DEFINE(HAVE_UNION_WAIT)
  88. fi
  89. AC_MSG_RESULT($make_cv_union_wait)
  90.  
  91. AC_DECL_SYS_SIGLIST
  92.  
  93. # The presence of the following is not meant to imply
  94. # that make necessarily works on those systems.
  95. AC_CHECK_LIB(sun, getpwnam)
  96.  
  97. AC_SUBST(REMOTE) REMOTE=stub
  98. AC_ARG_WITH(customs, [export jobs with the Customs daemon (NOT SUPPORTED)],
  99. [REMOTE=cstms LIBS="$LIBS libcustoms.a"])
  100.  
  101. echo checking for location of SCCS get command
  102. if test -f /usr/sccs/get; then
  103.   SCCS_GET=/usr/sccs/get
  104.   AC_DEFINE(SCCS_GET, "/usr/sccs/get")
  105. else
  106.   SCCS_GET=get
  107.   AC_DEFINE(SCCS_GET, "get")
  108. fi
  109. ac_clean_files="$ac_clean_files s.conftest conftoast" # Remove these later.
  110. if ( /usr/sccs/admin -n s.conftest || admin -n s.conftest ) >/dev/null 2>&1 &&
  111.    test -f s.conftest; then
  112.   # We successfully created an SCCS file.
  113.   echo checking if SCCS get command understands -G
  114.   if $SCCS_GET -Gconftoast s.conftest >/dev/null 2>&1 &&
  115.      test -f conftoast; then
  116.     AC_DEFINE(SCCS_GET_MINUS_G)
  117.   fi
  118. fi
  119. rm -f s.conftest conftoast
  120.  
  121. AC_OUTPUT(Makefile build.sh, [
  122. # Makefile uses this timestamp file to know when to remake Makefile,
  123. # build.sh, and glob/Makefile.
  124. touch stamp-config])
  125.  
  126. dnl Local Variables:
  127. dnl comment-start: "dnl "
  128. dnl comment-end: ""
  129. dnl comment-start-skip: "\\bdnl\\b\\s *"
  130. dnl compile-command: "make configure config.h.in"
  131. dnl End:
  132.